* Rotating disk test for projectors 
* after M.M. Rashid, Int. J. Numer. Methods Engrg. 55:413-450, 2002, DOI: 10.1002/nme.508
* Modified with different quadrants to generalize it
* in D. Dureisseix and H. Bavestrello, Computer Methods in Applied Mechanics and Engineering  195(44-47):6523-6541, 2006, DOI: 10.1016/j.cma.2006.02.003
*
* D. Dureisseix LMGC 2005/09/23
* D. Dureisseix LaMCoS 2017/10/20
* modified for newer Cast3m code version

* General options
OPTI DIME 2 ELEM TRI3;
* Radius of the disk
RAY1 = 1.;
* Special points
P1 = 0. 0.;
P2 = RAY1 0.;
P3 = RAY1 * ((COS 45.) (SIN 45.));
P4 = 0. RAY1;

* Fine mesh
L1 = P1 D 15 P2;
C1 = CERC 8 P2 P1 P3;
L2 = P3 D 15 P1;
CONT1 = L1 ET C1 ET L2;
MAIL1 = CONT1 SURF PLAN;
MAIL2 = MAIL1 ET (SYME MAIL1 DROIT P1 P3);
MESS (NBELEM MAIL2);

* Coarse mesh
L10 = P1 D 5 P2;
C10 = CERC 3 P2 P1 P3;
L20 = P3 D 5 P1;
CONT10 = L10 ET C10 ET L20;
MAIL10 = CONT10 SURF PLAN;
MAIL20 = MAIL10 ET (SYME MAIL10 DROIT P1 P3);
MAIL20 = MAIL20 SYME DROIT P1 P2;
MESS (NBELEM MAIL20);

* Final mesh
MAIL3 = MAIL2 ET MAIL20;
MAIL4 = MAIL3 ET (MAIL3 SYME DROIT P1 P4);
ELIM MAIL4 0.001;

* Analytical function at nodes
NMAIL4 = MAIL4 CHAN POI1;
NMAIL0 = DIFF NMAIL4 (MANU POI1 P1);
X1 Y1 = COOR NMAIL0;
IR1 = ((X1 ** 2) + (Y1 ** 2)) ** -0.5;
SIN1 = X1 * IR1;
COS1 = Y1 * IR1;
THETA1 = ATG SIN1 COS1;
THETA1 = CHAN THETA1 ATTRIBUT NATURE DIFFUS;
THETA1 = THETA1 ET (MANU CHPO P1 1 SCAL 0. NATURE DIFFUS);
X2 Y2 = COOR MAIL4;
R2 = (((X2 ** 2) + (Y2 ** 2)) ** 0.5) / RAY1;
CH1 = (20 * (R2 ** 2)) *
      ((R2 - 1.) ** 2) *
      (COS (2. * THETA1));

* Plots
TRAC CH1 MAIL4;
TRAC MAIL4;

* Write data into cercle.inp avs ucd file
OPTI SORT 'cercle';
SORT AVS MAIL4 CH1;
FIN;